안녕하세요, Michael입니다.
마우스 포인터를 TaskBar에 올린 상태에서 Ctrl 누르고 휠 돌리면 볼륨 조절됩니다.
아래 소스 입맛대로 고쳐쓰세요.
실행파일도 첨부합니다.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Settings
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

VolumeDegree    = 5
BarWidth        = 80
BarHeight       = 10
BarColor        = Fuchsia
BarShowTime     = 1000          ; milli-seconds
BarExist        = FALSE


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Functions
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

MouseIsOnTaskBar(ByRef iMouseX, ByRef iMouseY)
{
    CoordMode, Mouse, Screen
    MouseGetPos, iMouseX, iMouseY, id
    WinGetClass, class, ahk_id %id%

    if class = Shell_TrayWnd
        return TRUE
    else
        return FALSE
}

ShowVolumeBar(iMouseX, iMouseY)
{
    global BarWidth
    global BarHeight
    global BarColor
    global BarExist
    global BarShowTime
   
    SoundGet, MasterVol

    if BarExist = FALSE
    {
        BarPosX := iMouseX - BarWidth/2
        BarPosY := iMouseY - BarHeight - 16
        Progress, B X%BarPosX% Y%BarPosY% W%BarWidth% ZH%BarHeight% ZX0 ZY0 CB%BarColor% P%MasterVol%
        BarExist = TRUE
    }
    else
    {
        Progress, %MasterVol%
    }
       
    SetTimer, RemoveVolumeBar, %BarShowTime%
   
    return
}

; Timer
RemoveVolumeBar:
{
    SetTimer, RemoveVolumeBar, OFF
    Progress, OFF
    BarExist = FALSE
    return
}


;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Hotkeys
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

^WheelDown::
{
    if MouseIsOnTaskBar(iMouseX, iMouseY) = TRUE
    {
        SoundSet, -%VolumeDegree%
        ShowVolumeBar(iMouseX, iMouseY)
    }
    else
    {
        Send, ^{WheelDown}
    }
    return
}


^WheelUp::
{
    if MouseIsOnTaskBar(iMouseX, iMouseY) = TRUE
    {
        SoundSet, +%VolumeDegree%
        ShowVolumeBar(iMouseX, iMouseY)
    }
    else
    {
        Send, ^{WheelUp}
    }
    return
}

 

You would..
Share